| |
|
|
«Tipp für Wissensarbeiter: Daten zerlegen mit Excel 2007» |
|
| |
 Zürich, 23.02.2009 |
Excel 2007 bietet sich an, um Daten aus einem ERP-System für Preislisten, Statistiken und ähnliches aufzubereiten. Nur sprechen Unternehmensanwendung und Tabellenkalkulation oft nicht die selbe Sprache: Sind in den Stammdaten beispielsweise die gesuchte Seriennummer eines Produktes mit zusätzlichen Angaben wie Laufnummer, Ländercode oder Fertigungsstätte verknüpft, müssen die gesuchten Werte aus den importierten Daten extrahiert werden.
Für diese Aufgabe bietet Excel 2007 zahlreiche Such- und Zerlegungswerkzeuge. Im Folgenden stehen die Funktionen «TEIL» und «LÄNGE» in Kombination mit «FINDEN» im Zentrum.
Werte fixer Länge
Daten wie Seriennummern weisen oftmals eine vorgegebene Länge auf. Das erleichtert das Ausfiltern des gesuchten Werts. In folgendem Beispiel steht die mittlere Zahlenfolge «
6789
» für die gesuchte Seriennummer:
12345-6789-0123456
Die Excel-Formel muss also nach einem Minuszeichen suchen und die darauf folgenden vier Ziffern zurückgeben. Wenn der Wert in der Zelle A1 steht, erledigt
=TEIL(A1;FINDEN("-";A1)+1;4)
Werte variabler Länge
Die Angelegenheit verkompliziert sich, wenn die Länge der Seriennummer variiert. Im Beispiel
12345-6789-0123456
müssen Sie dann die Ziffern zwischen dem ersten und dem zweiten Minuszeichen extrahieren. Eine verschachtelte
FINDEN
-Funktion liefert die Stellen, an denen die Minuszeichen stehen.
FINDEN("-";A1)
stöbert dabei das erste Vorkommen auf.
Das zweite Minuszeichen finden Sie, indem Sie ab der Stelle nach dem ersten Minuszeichen suchen. Hierbei weisen Sie die Excel-Funktion an, erst dort mit der Suche zu starten. Das ergibt folgende Kombination von
FINDEN
-Befehlen:
=FINDEN("-";A1;FINDEN("-";A1)+1)
Nun können Sie die Länge der gesuchten Seriennummer ermitteln. Hierbei subtrahieren Sie die beiden
FINDEN
-Ergebnisse. Davon müssen Sie nochmals «
1
» abziehen, um nicht beim zweiten Minuszeichen, sondern bei der letzten Ziffer der Seriennummer zu landen. Die Länge der Seriennummer ergibt sich also aus folgender Formel:
=FINDEN("-";A1;FINDEN("-";A1)+1)- FINDEN("-";A1)-1
In obigem Beispiel entspräche das der Rechnung «
11-6-1
», was wiederum «
4
» ergibt.
Nun können Sie ihre Suchvorgänge mit der Funktion «
TEIL
» kombinieren, um die Seriennummer zu extrahieren:
=TEIL(A1;FINDEN("-";A1)+1;FINDEN("-";A1;FINDEN("-";A1)+1)-FINDEN("-";A1)-1)
Zum Abschluss noch die vergleichsweise einfache Variante: Im Beispiel
123456-7898
steht die Seriennummer am Schluss. Um deren Länge zu ermitteln, subtrahieren Sie die Position des Minuszeichens von der Gesamtlänge des Zellinhalts:
=LÄNGE(A1)-FINDEN("-";A1)
Mit der Funktion «
TEIL
» können Sie nun nach der Position des Minuszeichens suchen («
7
») und von der nächsten Stelle an mit obiger Formel die Seriennummer zurückgeben:
=TEIL(A1;FINDEN("-";A1)+1;LÄNGE(A1)-FINDEN("-";A1))
Die oben aufgeführten Beispiele finden Sie auch im Excel-Dokument. Wobei Sie sich nach all dieser trockenen Zahlen-Jongliererei wohl ohnehin eine Tasse Kaffee oder Tee verdient haben!
Die Tipps gibt es zweimal im Monat als E-mail-Newsletter frei Haus ins Postfach zugestellt: Excel, Word, E-Mail-Kommunikation, Collaboration, PowerPoint, Tipps für effizientere Meetings, MindMapping und vieles mehr.
Melden Sie sich jetzt für die dNews «Tipps und Tricks für Wissensarbeiter» an.
|
| |
|
 |
|
Tipp: Daten zerlegen mit Excel(PDF, 264KB)
Beispieldatei: Daten zerlegen mit Excel(XLS, 21KB)
RSS